Member Definitions

#r "../../src/Fabulous.AST/bin/Release/netstandard2.1/publish/Fantomas.Core.dll"
#r "../../src/Fabulous.AST/bin/Release/netstandard2.1/publish/Fabulous.AST.dll"
#r "../../src/Fabulous.AST/bin/Release/netstandard2.1/publish/Fantomas.FCS.dll"

open Fabulous.AST
open type Fabulous.AST.Ast

Oak() {
    AnonymousModule() {
        Open("System")

        TypeDefn(
            "Person",
            Constructor(
                ParenPat(
                    TuplePat(
                        [ ParameterPat("name", String())
                          ParameterPat("middle", String())
                          ParameterPat("?lastName", String())
                          ParameterPat("?age", Int()) ]
                    )
                )
            )
        ) {
            LetBindings(
                [ Value("_age", "defaultArg age 18").returnType(Int()).toMutable()
                  Function(
                      "Create",
                      [ "name"; "middle" ],
                      NewExpr(LongIdent "Person", ParenExpr(TupleExpr([ "name"; "middle" ])))
                  ) ]
            )

            Constructor(
                ParenPat(TuplePat([ Constant "name"; Constant "middle" ])),
                NewExpr(LongIdent "Person", ParenExpr(TupleExpr([ "name"; "middle" ])))
            )

            Member(
                "Create2",
                ParenPat(TuplePat [ "name"; "middle" ]),
                NewExpr(LongIdent "Person", ParenExpr(TupleExpr([ "name"; "middle" ])))
            )
                .toStatic()

            Member("this.Name", "name")

            MemberVal("Middle", "middle", true)

            MemberVal("LastName", "lastName", true, true)

            Member(
                "this.Age",
                Getter(ConstantExpr(Constant("_age"))),
                Setter(ParenPat(NamedPat("value")), LongIdentSetExpr("_age", "value"))
            )

            AbstractMember("GetValue", [ Unit() ], String())

            Default("this.GetValue", UnitPat(), ConstantExpr(String("Hello World")))

            InterfaceWith("IDisposable") { Member("this.Dispose", UnitPat(), ConstantUnit()) }
        }
    }
}
|> Gen.mkOak
|> Gen.run
|> printfn "%s"

// produces the following code:

open System

type Person(name: string, middle: string, ?lastName: string, ?age: int) =
    let mutable _age: int = defaultArg age 18
    let Create name middle = new Person(name, middle)

    new(name, middle) = new Person(name, middle)
    static member Create2(name, middle) = new Person(name, middle)
    member this.Name = name
    member val Middle = middle with get
    member val LastName = lastName with get, set

    member this.Age
        with get () = _age
        and set (value) = _age <- value

    abstract GetValue: unit -> string
    default this.GetValue() = "Hello World"

    interface IDisposable with
        member this.Dispose() = ()